MIN
MIN(list)
Gives the smallest value in a list, such as the earliest start among a task's successors, or the smaller of two values. When there are no values it is blank, not 0, so a task with no successors gets an empty cell rather than a misleading zero.
Arguments
| Argument | What to give it |
|---|---|
| list | A column read from a set of rows, like Successors[Start date], or several single values: MIN([Total float], [Free float]). Numbers, durations, dates or text. Blanks are skipped. It also takes one level over time (see below). |
Examples
Formula=MIN(Successors[Start date])
The earliest start among the task's successors.
Formula=MIN(Upstream[Total float])
The least float on any task leading into this one: how close the work feeding it runs to critical.
Formula=MIN([Total float], [Free float])
The smaller of the task's two floats.
Measure (on the project)=MIN(Tasks[Start date])
As a measure: the first start in the schedule.
Formula=MIN(HISTORY(INDAYS([Total float])))
The least total float, in days, the task has had at any update. MIN of one level over time gives its lowest point.
Reach for something else when
| You want | Use |
|---|---|
| The largest value | MAX |
| The task that has the smallest value, not the value | ARGMIN |
| A floor or a ceiling on one value | CLAMP |
| The value a share of the list falls below | PERCENTILE |
Common questions
Why is MIN blank on some rows?
There were no values: the set was empty, or the column was blank on every row of it. Total float, for one, is blank once a task is complete. To show a value instead, wrap it in COALESCE.
Do blanks count as 0?
No, they are skipped, with several single values too: MIN([Total float], 5d) is 5d on a complete task, whose total float is blank.
How does MIN compare text?
Alphabetically, ignoring case.
What does "MIN takes one list, or several single values" mean?
A list and a single value were mixed in one MIN.
The editor refuses this=MIN(Successors[Start date], [Finish date])
Take the list's MIN first, then compare: MIN(MIN(Successors[Start date]), [Finish date]).
Can I take the MIN of an amount over time?
No. MIN reads a level over time, such as a crew size or a float as of each update. An amount, such as hours spread over the task, has no low point to read: add it up with TOTAL, or read it on a date with AT. See amounts and levels.